src/runtime/sys_freebsd_386.s

   1 // Copyright 2009 The Go Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style
   3 // license that can be found in the LICENSE file.
   4 //
   5 // System calls and other sys.stuff for 386, FreeBSD
   6 // /usr/src/sys/kern/syscalls.master for syscall numbers.
   7 //
   8
   9 #include "go_asm.h"
  10 #include "go_tls.h"
  11 #include "textflag.h"
  12
  13 TEXT runtime·sys_umtx_op(SB),NOSPLIT,$-4
  14         MOVL    $454, AX
  15         INT     $0x80
  16         MOVL    AX, ret+20(FP)
  17         RET
  18
  19 TEXT runtime·thr_new(SB),NOSPLIT,$-4
  20         MOVL    $455, AX
  21         INT     $0x80
  22         RET
  23
  24 TEXT runtime·thr_start(SB),NOSPLIT,$0
  25         MOVL    mm+0(FP), AX
  26         MOVL    m_g0(AX), BX
  27         LEAL    m_tls(AX), BP
  28         MOVL    0(BP), DI
  29         ADDL    $7, DI
  30         PUSHAL
  31         PUSHL   $32
  32         PUSHL   BP
  33         PUSHL   DI
  34         CALL    runtime·setldt(SB)
  35         POPL    AX
  36         POPL    AX
  37         POPL    AX
  38         POPAL
  39         get_tls(CX)
  40         MOVL    BX, g(CX)
  41
  42         MOVL    AX, g_m(BX)
  43         CALL    runtime·stackcheck(SB)         // smashes AX
  44         CALL    runtime·mstart(SB)
  45
  46         MOVL    0, AX                   // crash (not reached)
  47
  48 // Exit the entire program (like C exit)
  49 TEXT runtime·exit(SB),NOSPLIT,$-4
  50         MOVL    $1, AX
  51         INT     $0x80
  52         MOVL    $0xf1, 0xf1  // crash
  53         RET
  54
  55 TEXT runtime·exit1(SB),NOSPLIT,$-4
  56         MOVL    $431, AX
  57         INT     $0x80
  58         JAE     2(PC)
  59         MOVL    $0xf1, 0xf1  // crash
  60         RET
  61
  62 TEXT runtime·open(SB),NOSPLIT,$-4
  63         MOVL    $5, AX
  64         INT     $0x80
  65         MOVL    AX, ret+12(FP)
  66         RET
  67
  68 TEXT runtime·close(SB),NOSPLIT,$-4
  69         MOVL    $6, AX
  70         INT     $0x80
  71         MOVL    AX, ret+4(FP)
  72         RET
  73
  74 TEXT runtime·read(SB),NOSPLIT,$-4
  75         MOVL    $3, AX
  76         INT     $0x80
  77         MOVL    AX, ret+12(FP)
  78         RET
  79
  80 TEXT runtime·write(SB),NOSPLIT,$-4
  81         MOVL    $4, AX
  82         INT     $0x80
  83         MOVL    AX, ret+12(FP)
  84         RET
  85
  86 TEXT runtime·getrlimit(SB),NOSPLIT,$-4
  87         MOVL    $194, AX
  88         INT     $0x80
  89         MOVL    AX, ret+8(FP)
  90         RET
  91
  92 TEXT runtime·raise(SB),NOSPLIT,$16
  93         // thr_self(&8(SP))
  94         LEAL    8(SP), AX
  95         MOVL    AX, 4(SP)
  96         MOVL    $432, AX
  97         INT     $0x80
  98         // thr_kill(self, SIGPIPE)
  99         MOVL    8(SP), AX
 100         MOVL    AX, 4(SP)
 101         MOVL    sig+0(FP), AX
 102         MOVL    AX, 8(SP)
 103         MOVL    $433, AX
 104         INT     $0x80
 105         RET
 106
 107 TEXT runtime·mmap(SB),NOSPLIT,$32
 108         LEAL addr+0(FP), SI
 109         LEAL    4(SP), DI
 110         CLD
 111         MOVSL
 112         MOVSL
 113         MOVSL
 114         MOVSL
 115         MOVSL
 116         MOVSL
 117         MOVL    $0, AX  // top 32 bits of file offset
 118         STOSL
 119         MOVL    $477, AX
 120         INT     $0x80
 121         MOVL    AX, ret+24(FP)
 122         RET
 123
 124 TEXT runtime·munmap(SB),NOSPLIT,$-4
 125         MOVL    $73, AX
 126         INT     $0x80
 127         JAE     2(PC)
 128         MOVL    $0xf1, 0xf1  // crash
 129         RET
 130
 131 TEXT runtime·madvise(SB),NOSPLIT,$-4
 132         MOVL    $75, AX // madvise
 133         INT     $0x80
 134         // ignore failure - maybe pages are locked
 135         RET
 136
 137 TEXT runtime·setitimer(SB), NOSPLIT, $-4
 138         MOVL    $83, AX
 139         INT     $0x80
 140         RET
 141
 142 // func now() (sec int64, nsec int32)
 143 TEXT time·now(SB), NOSPLIT, $32
 144         MOVL    $232, AX
 145         LEAL    12(SP), BX
 146         MOVL    $0, 4(SP)       // CLOCK_REALTIME
 147         MOVL    BX, 8(SP)
 148         INT     $0x80
 149         MOVL    12(SP), AX      // sec
 150         MOVL    16(SP), BX      // nsec
 151
 152         // sec is in AX, nsec in BX
 153         MOVL    AX, sec+0(FP)
 154         MOVL    $0, sec+4(FP)
 155         MOVL    BX, nsec+8(FP)
 156         RET
 157
 158 // int64 nanotime(void) so really
 159 // void nanotime(int64 *nsec)
 160 TEXT runtime·nanotime(SB), NOSPLIT, $32
 161         MOVL    $232, AX
 162         LEAL    12(SP), BX
 163         // We can use CLOCK_MONOTONIC_FAST here when we drop
 164         // support for FreeBSD 8-STABLE.
 165         MOVL    $4, 4(SP)       // CLOCK_MONOTONIC
 166         MOVL    BX, 8(SP)
 167         INT     $0x80
 168         MOVL    12(SP), AX      // sec
 169         MOVL    16(SP), BX      // nsec
 170
 171         // sec is in AX, nsec in BX
 172         // convert to DX:AX nsec
 173         MOVL    $1000000000, CX
 174         MULL    CX
 175         ADDL    BX, AX
 176         ADCL    $0, DX
 177
 178         MOVL    AX, ret_lo+0(FP)
 179         MOVL    DX, ret_hi+4(FP)
 180         RET
 181
 182
 183 TEXT runtime·sigaction(SB),NOSPLIT,$-4
 184         MOVL    $416, AX
 185         INT     $0x80
 186         JAE     2(PC)
 187         MOVL    $0xf1, 0xf1  // crash
 188         RET
 189
 190 TEXT runtime·sigtramp(SB),NOSPLIT,$44
 191         get_tls(CX)
 192
 193         // check that g exists
 194         MOVL    g(CX), DI
 195         CMPL    DI, $0
 196         JNE     6(PC)
 197         MOVL    signo+0(FP), BX
 198         MOVL    BX, 0(SP)
 199         MOVL    $runtime·badsignal(SB), AX
 200         CALL    AX
 201         JMP     ret
 202
 203         // save g
 204         MOVL    DI, 20(SP)
 205
 206         // g = m->gsignal
 207         MOVL    g_m(DI), BX
 208         MOVL    m_gsignal(BX), BX
 209         MOVL    BX, g(CX)
 210
 211         // copy arguments for call to sighandler
 212         MOVL    signo+0(FP), BX
 213         MOVL    BX, 0(SP)
 214         MOVL    info+4(FP), BX
 215         MOVL    BX, 4(SP)
 216         MOVL    context+8(FP), BX
 217         MOVL    BX, 8(SP)
 218         MOVL    DI, 12(SP)
 219
 220         CALL    runtime·sighandler(SB)
 221
 222         // restore g
 223         get_tls(CX)
 224         MOVL    20(SP), BX
 225         MOVL    BX, g(CX)
 226
 227 ret:
 228         // call sigreturn
 229         MOVL    context+8(FP), AX
 230         MOVL    $0, 0(SP)       // syscall gap
 231         MOVL    AX, 4(SP)
 232         MOVL    $417, AX        // sigreturn(ucontext)
 233         INT     $0x80
 234         MOVL    $0xf1, 0xf1  // crash
 235         RET
 236
 237 TEXT runtime·sigaltstack(SB),NOSPLIT,$0
 238         MOVL    $53, AX
 239         INT     $0x80
 240         JAE     2(PC)
 241         MOVL    $0xf1, 0xf1  // crash
 242         RET
 243
 244 TEXT runtime·usleep(SB),NOSPLIT,$20
 245         MOVL    $0, DX
 246         MOVL    usec+0(FP), AX
 247         MOVL    $1000000, CX
 248         DIVL    CX
 249         MOVL    AX, 12(SP)              // tv_sec
 250         MOVL    $1000, AX
 251         MULL    DX
 252         MOVL    AX, 16(SP)              // tv_nsec
 253
 254         MOVL    $0, 0(SP)
 255         LEAL    12(SP), AX
 256         MOVL    AX, 4(SP)               // arg 1 - rqtp
 257         MOVL    $0, 8(SP)               // arg 2 - rmtp
 258         MOVL    $240, AX                // sys_nanosleep
 259         INT     $0x80
 260         RET
 261
 262 /*
 263 descriptor entry format for system call
 264 is the native machine format, ugly as it is:
 265
 266         2-byte limit
 267         3-byte base
 268         1-byte: 0x80=present, 0x60=dpl<<5, 0x1F=type
 269         1-byte: 0x80=limit is *4k, 0x40=32-bit operand size,
 270                 0x0F=4 more bits of limit
 271         1 byte: 8 more bits of base
 272
 273 int i386_get_ldt(int, union ldt_entry *, int);
 274 int i386_set_ldt(int, const union ldt_entry *, int);
 275
 276 */
 277
 278 // setldt(int entry, int address, int limit)
 279 TEXT runtime·setldt(SB),NOSPLIT,$32
 280         MOVL    address+4(FP), BX       // aka base
 281         // see comment in sys_linux_386.s; freebsd is similar
 282         ADDL    $0x8, BX
 283
 284         // set up data_desc
 285         LEAL    16(SP), AX      // struct data_desc
 286         MOVL    $0, 0(AX)
 287         MOVL    $0, 4(AX)
 288
 289         MOVW    BX, 2(AX)
 290         SHRL    $16, BX
 291         MOVB    BX, 4(AX)
 292         SHRL    $8, BX
 293         MOVB    BX, 7(AX)
 294
 295         MOVW    $0xffff, 0(AX)
 296         MOVB    $0xCF, 6(AX)    // 32-bit operand, 4k limit unit, 4 more bits of limit
 297
 298         MOVB    $0xF2, 5(AX)    // r/w data descriptor, dpl=3, present
 299
 300         // call i386_set_ldt(entry, desc, 1)
 301         MOVL    $0xffffffff, 0(SP)      // auto-allocate entry and return in AX
 302         MOVL    AX, 4(SP)
 303         MOVL    $1, 8(SP)
 304         CALL    runtime·i386_set_ldt(SB)
 305
 306         // compute segment selector - (entry*8+7)
 307         SHLL    $3, AX
 308         ADDL    $7, AX
 309         MOVW    AX, GS
 310         RET
 311
 312 TEXT runtime·i386_set_ldt(SB),NOSPLIT,$16
 313         LEAL    args+0(FP), AX  // 0(FP) == 4(SP) before SP got moved
 314         MOVL    $0, 0(SP)       // syscall gap
 315         MOVL    $1, 4(SP)
 316         MOVL    AX, 8(SP)
 317         MOVL    $165, AX
 318         INT     $0x80
 319         JAE     2(PC)
 320         INT     $3
 321         RET
 322
 323 TEXT runtime·sysctl(SB),NOSPLIT,$28
 324         LEAL    mib+0(FP), SI
 325         LEAL    4(SP), DI
 326         CLD
 327         MOVSL                           // arg 1 - name
 328         MOVSL                           // arg 2 - namelen
 329         MOVSL                           // arg 3 - oldp
 330         MOVSL                           // arg 4 - oldlenp
 331         MOVSL                           // arg 5 - newp
 332         MOVSL                           // arg 6 - newlen
 333         MOVL    $202, AX                // sys___sysctl
 334         INT     $0x80
 335         JAE     4(PC)
 336         NEGL    AX
 337         MOVL    AX, ret+24(FP)
 338         RET
 339         MOVL    $0, AX
 340         MOVL    AX, ret+24(FP)
 341         RET
 342
 343 TEXT runtime·osyield(SB),NOSPLIT,$-4
 344         MOVL    $331, AX                // sys_sched_yield
 345         INT     $0x80
 346         RET
 347
 348 TEXT runtime·sigprocmask(SB),NOSPLIT,$16
 349         MOVL    $0, 0(SP)               // syscall gap
 350         MOVL    $3, 4(SP)               // arg 1 - how (SIG_SETMASK)
 351         MOVL    new+0(FP), AX
 352         MOVL    AX, 8(SP)               // arg 2 - set
 353         MOVL    old+4(FP), AX
 354         MOVL    AX, 12(SP)              // arg 3 - oset
 355         MOVL    $340, AX                // sys_sigprocmask
 356         INT     $0x80
 357         JAE     2(PC)
 358         MOVL    $0xf1, 0xf1  // crash
 359         RET
 360
 361 // int32 runtime·kqueue(void);
 362 TEXT runtime·kqueue(SB),NOSPLIT,$0
 363         MOVL    $362, AX
 364         INT     $0x80
 365         JAE     2(PC)
 366         NEGL    AX
 367         MOVL    AX, ret+0(FP)
 368         RET
 369
 370 // int32 runtime·kevent(int kq, Kevent *changelist, int nchanges, Kevent *eventlist, int nevents, Timespec *timeout);
 371 TEXT runtime·kevent(SB),NOSPLIT,$0
 372         MOVL    $363, AX
 373         INT     $0x80
 374         JAE     2(PC)
 375         NEGL    AX
 376         MOVL    AX, ret+24(FP)
 377         RET
 378
 379 // int32 runtime·closeonexec(int32 fd);
 380 TEXT runtime·closeonexec(SB),NOSPLIT,$32
 381         MOVL    $92, AX         // fcntl
 382         // 0(SP) is where the caller PC would be; kernel skips it
 383         MOVL    fd+0(FP), BX
 384         MOVL    BX, 4(SP)       // fd
 385         MOVL    $2, 8(SP)       // F_SETFD
 386         MOVL    $1, 12(SP)      // FD_CLOEXEC
 387         INT     $0x80
 388         JAE     2(PC)
 389         NEGL    AX
 390         RET
 391
 392 GLOBL runtime·tlsoffset(SB),NOPTR,$4