src/runtime/cgo/asm_arm.s

   1 // Copyright 2012 The Go Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style
   3 // license that can be found in the LICENSE file.
   4
   5 #include "textflag.h"
   6
   7 // Called by C code generated by cmd/cgo.
   8 // func crosscall2(fn, a unsafe.Pointer, n int32, ctxt uintptr)
   9 // Saves C callee-saved registers and calls cgocallback with three arguments.
  10 // fn is the PC of a func(a unsafe.Pointer) function.
  11 TEXT crosscall2(SB),NOSPLIT|NOFRAME,$0
  12         SUB     $(8*9), R13 // Reserve space for the floating point registers.
  13         // The C arguments arrive in R0, R1, R2, and R3. We want to
  14         // pass R0, R1, and R3 to Go, so we push those on the stack.
  15         // Also, save C callee-save registers R4-R12.
  16         MOVM.WP [R0, R1, R3, R4, R5, R6, R7, R8, R9, g, R11, R12], (R13)
  17         // Finally, save the link register R14. This also puts the
  18         // arguments we pushed for cgocallback where they need to be,
  19         // starting at 4(R13).
  20         MOVW.W  R14, -4(R13)
  21
  22         // Skip floating point registers on GOARM < 6.
  23         MOVB    runtime·goarm(SB), R11
  24         CMP $6, R11
  25         BLT skipfpsave
  26         MOVD    F8, (13*4+8*1)(R13)
  27         MOVD    F9, (13*4+8*2)(R13)
  28         MOVD    F10, (13*4+8*3)(R13)
  29         MOVD    F11, (13*4+8*4)(R13)
  30         MOVD    F12, (13*4+8*5)(R13)
  31         MOVD    F13, (13*4+8*6)(R13)
  32         MOVD    F14, (13*4+8*7)(R13)
  33         MOVD    F15, (13*4+8*8)(R13)
  34
  35 skipfpsave:
  36         BL      runtime·load_g(SB)
  37         // We set up the arguments to cgocallback when saving registers above.
  38         BL      runtime·cgocallback(SB)
  39
  40         MOVB    runtime·goarm(SB), R11
  41         CMP $6, R11
  42         BLT skipfprest
  43         MOVD    (13*4+8*1)(R13), F8
  44         MOVD    (13*4+8*2)(R13), F9
  45         MOVD    (13*4+8*3)(R13), F10
  46         MOVD    (13*4+8*4)(R13), F11
  47         MOVD    (13*4+8*5)(R13), F12
  48         MOVD    (13*4+8*6)(R13), F13
  49         MOVD    (13*4+8*7)(R13), F14
  50         MOVD    (13*4+8*8)(R13), F15
  51
  52 skipfprest:
  53         MOVW.P  4(R13), R14
  54         MOVM.IAW        (R13), [R0, R1, R3, R4, R5, R6, R7, R8, R9, g, R11, R12]
  55         ADD     $(8*9), R13
  56         MOVW    R14, R15