src/race.bat

   1 :: Copyright 2013 The Go Authors. All rights reserved.
   2 :: Use of this source code is governed by a BSD-style
   3 :: license that can be found in the LICENSE file.
   4
   5 :: race.bash tests the standard library under the race detector.
   6 :: http://golang.org/doc/articles/race_detector.html
   7
   8 @echo off
   9
  10 setlocal
  11
  12 if exist make.bat goto ok
  13 echo race.bat must be run from go\src
  14 :: cannot exit: would kill parent command interpreter
  15 goto end
  16 :ok
  17
  18 call make.bat --dist-tool >NUL
  19 if errorlevel 1 goto fail
  20 .\cmd\dist\dist env -wp >env.bat
  21 if errorlevel 1 goto fail
  22 call env.bat
  23 del env.bat
  24
  25 if %GOHOSTARCH% == amd64 goto continue
  26 echo Race detector is only supported on windows/amd64.
  27 goto fail
  28
  29 :continue
  30 call make.bat --no-banner --no-local
  31 if %GOBUILDFAIL%==1 goto end
  32 :: golang.org/issue/5537 - we must build a race enabled cmd/cgo before trying to use it.
  33 echo # go install -race cmd/cgo
  34 go install -race cmd/cgo
  35 echo # go install -race std
  36 go install -race std
  37 if errorlevel 1 goto fail
  38 echo # go test -race -short -std
  39 go test -race -short std
  40 if errorlevel 1 goto fail
  41 echo # go test -race -run=nothingplease -bench=.* -benchtime=.1s -cpu=4 std
  42 go test -race -run=nothingplease -bench=.* -benchtime=.1s -cpu=4 std
  43 if errorlevel 1 goto fail
  44 goto succ
  45
  46 :fail
  47 set GOBUILDFAIL=1
  48 echo Fail.
  49 goto end
  50
  51 :succ
  52 echo All tests passed.
  53
  54 :end
  55