src/make.bat

   1 :: Copyright 2012 The Go Authors. All rights reserved.
   2 :: Use of this source code is governed by a BSD-style
   3 :: license that can be found in the LICENSE file.
   4
   5 :: Environment variables that control make.bat:
   6 ::
   7 :: GOROOT_FINAL: The expected final Go root, baked into binaries.
   8 :: The default is the location of the Go tree during the build.
   9 ::
  10 :: GOHOSTARCH: The architecture for host tools (compilers and
  11 :: binaries).  Binaries of this type must be executable on the current
  12 :: system, so the only common reason to set this is to set
  13 :: GOHOSTARCH=386 on an amd64 machine.
  14 ::
  15 :: GOARCH: The target architecture for installed packages and tools.
  16 ::
  17 :: GOOS: The target operating system for installed packages and tools.
  18 ::
  19 :: GO_GCFLAGS: Additional 5g/6g/8g arguments to use when
  20 :: building the packages and commands.
  21 ::
  22 :: GO_LDFLAGS: Additional 5l/6l/8l arguments to use when
  23 :: building the commands.
  24 ::
  25 :: CGO_ENABLED: Controls cgo usage during the build. Set it to 1
  26 :: to include all cgo related files, .c and .go file with "cgo"
  27 :: build directive, in the build. Set it to 0 to ignore them.
  28
  29 @echo off
  30
  31 :: Keep environment variables within this script
  32 :: unless invoked with --no-local.
  33 if x%1==x--no-local goto nolocal
  34 if x%2==x--no-local goto nolocal
  35 setlocal
  36 :nolocal
  37
  38 set GOBUILDFAIL=0
  39
  40 if exist make.bat goto ok
  41 echo Must run make.bat from Go src directory.
  42 goto fail
  43 :ok
  44
  45 :: Clean old generated file that will cause problems in the build.
  46 del /F ".\pkg\runtime\runtime_defs.go" 2>NUL
  47
  48 :: Set GOROOT for build.
  49 cd ..
  50 set GOROOT=%CD%
  51 cd src
  52
  53 echo ##### Building Go bootstrap tool.
  54 echo cmd/dist
  55 if not exist ..\bin\tool mkdir ..\bin\tool
  56 if "x%GOROOT_BOOTSTRAP%"=="x" set GOROOT_BOOTSTRAP=%HOMEDRIVE%%HOMEPATH%\Go1.4
  57 if not exist "%GOROOT_BOOTSTRAP%\bin\go.exe" goto bootstrapfail
  58 setlocal
  59 set GOROOT=%GOROOT_BOOTSTRAP%
  60 set GOOS=
  61 set GOARCH=
  62 "%GOROOT_BOOTSTRAP%\bin\go" build -o cmd\dist\dist.exe .\cmd\dist
  63 endlocal
  64 if errorlevel 1 goto fail
  65 .\cmd\dist\dist env -w -p >env.bat
  66 if errorlevel 1 goto fail
  67 call env.bat
  68 del env.bat
  69 echo.
  70
  71 if x%1==x--dist-tool goto copydist
  72 if x%2==x--dist-tool goto copydist
  73
  74 set buildall=-a
  75 if x%1==x--no-clean set buildall=
  76 .\cmd\dist\dist bootstrap %buildall% -v
  77 if errorlevel 1 goto fail
  78 :: Delay move of dist tool to now, because bootstrap cleared tool directory.
  79 move .\cmd\dist\dist.exe "%GOTOOLDIR%\dist.exe"
  80 echo.
  81
  82 if not %GOHOSTARCH% == %GOARCH% goto localbuild
  83 if not %GOHOSTOS% == %GOOS% goto localbuild
  84 goto mainbuild
  85
  86 :localbuild
  87 echo ##### Building tools for local system. %GOHOSTOS%/%GOHOSTARCH%
  88 setlocal
  89 set GOOS=%GOHOSTOS%
  90 set GOARCH=%GOHOSTARCH%
  91 "%GOTOOLDIR%\go_bootstrap" install -gcflags "%GO_GCFLAGS%" -ldflags "%GO_LDFLAGS%" -v std cmd
  92 endlocal
  93 if errorlevel 1 goto fail
  94 echo.
  95
  96 :mainbuild
  97 echo ##### Building packages and commands.
  98 "%GOTOOLDIR%\go_bootstrap" install -gcflags "%GO_GCFLAGS%" -ldflags "%GO_LDFLAGS%" -a -v std cmd
  99 if errorlevel 1 goto fail
 100 del "%GOTOOLDIR%\go_bootstrap.exe"
 101 echo.
 102
 103 if x%1==x--no-banner goto nobanner
 104 "%GOTOOLDIR%\dist" banner
 105 :nobanner
 106
 107 goto end
 108
 109 :copydist
 110 mkdir "%GOTOOLDIR%" 2>NUL
 111 copy cmd\dist\dist.exe "%GOTOOLDIR%\"
 112 goto end
 113
 114 :bootstrapfail
 115 echo ERROR: Cannot find %GOROOT_BOOTSTRAP%\bin\go.exe
 116 echo "Set GOROOT_BOOTSTRAP to a working Go tree >= Go 1.4."
 117
 118 :fail
 119 set GOBUILDFAIL=1
 120 if x%GOBUILDEXIT%==x1 exit %GOBUILDFAIL%
 121
 122 :end