src/make.bat

   1 :: Copyright 2012 The Go Authors. All rights reserved.
   2 :: Use of this source code is governed by a BSD-style
   3 :: license that can be found in the LICENSE file.
   4
   5 :: Environment variables that control make.bat:
   6 ::
   7 :: GOROOT_FINAL: The expected final Go root, baked into binaries.
   8 :: The default is the location of the Go tree during the build.
   9 ::
  10 :: GOHOSTARCH: The architecture for host tools (compilers and
  11 :: binaries).  Binaries of this type must be executable on the current
  12 :: system, so the only common reason to set this is to set
  13 :: GOHOSTARCH=386 on an amd64 machine.
  14 ::
  15 :: GOARCH: The target architecture for installed packages and tools.
  16 ::
  17 :: GOOS: The target operating system for installed packages and tools.
  18 ::
  19 :: GO_GCFLAGS: Additional go tool compile arguments to use when
  20 :: building the packages and commands.
  21 ::
  22 :: GO_LDFLAGS: Additional go tool link arguments to use when
  23 :: building the commands.
  24 ::
  25 :: CGO_ENABLED: Controls cgo usage during the build. Set it to 1
  26 :: to include all cgo related files, .c and .go file with "cgo"
  27 :: build directive, in the build. Set it to 0 to ignore them.
  28 ::
  29 :: CC: Command line to run to compile C code for GOHOSTARCH.
  30 :: Default is "gcc".
  31 ::
  32 :: CC_FOR_TARGET: Command line to run compile C code for GOARCH.
  33 :: This is used by cgo. Default is CC.
  34 ::
  35 :: FC: Command line to run to compile Fortran code.
  36 :: This is used by cgo. Default is "gfortran".
  37
  38 @echo off
  39
  40 :: Keep environment variables within this script
  41 :: unless invoked with --no-local.
  42 if x%1==x--no-local goto nolocal
  43 if x%2==x--no-local goto nolocal
  44 if x%3==x--no-local goto nolocal
  45 if x%4==x--no-local goto nolocal
  46 setlocal
  47 :nolocal
  48
  49 set GOBUILDFAIL=0
  50 set GOFLAGS=
  51 set GO111MODULE=
  52
  53 if exist make.bat goto ok
  54 echo Must run make.bat from Go src directory.
  55 goto fail
  56 :ok
  57
  58 :: Clean old generated file that will cause problems in the build.
  59 del /F ".\pkg\runtime\runtime_defs.go" 2>NUL
  60
  61 :: Set GOROOT for build.
  62 cd ..
  63 set GOROOT=%CD%
  64 cd src
  65 set vflag=
  66 if x%1==x-v set vflag=-v
  67 if x%2==x-v set vflag=-v
  68 if x%3==x-v set vflag=-v
  69 if x%4==x-v set vflag=-v
  70
  71 if not exist ..\bin\tool mkdir ..\bin\tool
  72 if "x%GOROOT_BOOTSTRAP%"=="x" set GOROOT_BOOTSTRAP=%HOMEDRIVE%%HOMEPATH%\Go1.4
  73 if not exist "%GOROOT_BOOTSTRAP%\bin\go.exe" goto bootstrapfail
  74 echo Building Go cmd/dist using %GOROOT_BOOTSTRAP%
  75 if x%vflag==x-v echo cmd/dist
  76 setlocal
  77 set GOROOT=%GOROOT_BOOTSTRAP%
  78 set GOOS=
  79 set GOARCH=
  80 set GOBIN=
  81 "%GOROOT_BOOTSTRAP%\bin\go.exe" build -o cmd\dist\dist.exe .\cmd\dist
  82 endlocal
  83 if errorlevel 1 goto fail
  84 .\cmd\dist\dist.exe env -w -p >env.bat
  85 if errorlevel 1 goto fail
  86 call env.bat
  87 del env.bat
  88 if x%vflag==x-v echo.
  89
  90 if x%1==x--dist-tool goto copydist
  91 if x%2==x--dist-tool goto copydist
  92 if x%3==x--dist-tool goto copydist
  93 if x%4==x--dist-tool goto copydist
  94
  95 set buildall=-a
  96 if x%1==x--no-clean set buildall=
  97 if x%2==x--no-clean set buildall=
  98 if x%3==x--no-clean set buildall=
  99 if x%4==x--no-clean set buildall=
 100 if x%1==x--no-banner set buildall=%buildall% --no-banner
 101 if x%2==x--no-banner set buildall=%buildall% --no-banner
 102 if x%3==x--no-banner set buildall=%buildall% --no-banner
 103 if x%4==x--no-banner set buildall=%buildall% --no-banner
 104
 105 :: Run dist bootstrap to complete make.bash.
 106 :: Bootstrap installs a proper cmd/dist, built with the new toolchain.
 107 :: Throw ours, built with Go 1.4, away after bootstrap.
 108 .\cmd\dist\dist.exe bootstrap %vflag% %buildall%
 109 if errorlevel 1 goto fail
 110 del .\cmd\dist\dist.exe
 111 goto end
 112
 113 :: DO NOT ADD ANY NEW CODE HERE.
 114 :: The bootstrap+del above are the final step of make.bat.
 115 :: If something must be added, add it to cmd/dist's cmdbootstrap,
 116 :: to avoid needing three copies in three different shell languages
 117 :: (make.bash, make.bat, make.rc).
 118
 119 :copydist
 120 mkdir "%GOTOOLDIR%" 2>NUL
 121 copy cmd\dist\dist.exe "%GOTOOLDIR%\"
 122 goto end
 123
 124 :bootstrapfail
 125 echo ERROR: Cannot find %GOROOT_BOOTSTRAP%\bin\go.exe
 126 echo Set GOROOT_BOOTSTRAP to a working Go tree ^>= Go 1.4.
 127
 128 :fail
 129 set GOBUILDFAIL=1
 130 if x%GOBUILDEXIT%==x1 exit %GOBUILDFAIL%
 131
 132 :end